Решение вычислительных задач по геодезии с помощью электронных таблиц ms Excel Расчет углов треугольника с помощью электронных таблиц ms Excel
Рассмотрим решение тестового примера по расчету углов треугольника с помощью программы MS Excel. Предположим, что координаты вершин треугольника заданы в ячейках: x1-A2, y1-B2, x2-C2, y2-D2, x3-E2, y3-F2.
Если запланировать ячейку G2, например, под хранение длины стороны AB, то в нее необходимо записать формулу (через строку формул):
=КОРЕНЬ((A2-C2)*(A2-C2)+(B2-D2)*(B2-D2)).
Здесь используется функция вычисления квадратного корня, конструкция (A2-C2)*(A2-C2) соответствует возведению в квадрат выражения в скобках (можно было бы так же использовать конструкцию (A2-C2)^2). Для сторон BC и AC следует поступить аналогично, выделив, например, под них ячейки H2 и I2.
Для вычисления величины угла А в ячейку A6 необходимо поместить формулу:
=(180/ПИ())*ACOS((G2*G2+I2*I2-H2*H2)/(2*G2*I2)).
Здесь ACOS обозначает вычисление функции арккосинус, G2*G2 – возведение в квадрат, конструкция ПИ() возвращает значение математической константы , множитель 180/ПИ() используется для перевода в градусы величины полученной в радианах. Без этого множителя будет вычислена радианная мера угла. Для перевода из градусов в радианы необходимо использовать множитель ПИ()/180.
Для вычисления величин углов B и C используем ячейки B6 и C6, поместив в них соответствующие формулы, аналогичные последней.
Таким образом, в ячейках A6, B6 и C6 будем иметь величины искомых углов в градусах и долях. Для проверки расчетов в ячейку E6 следует поместить формулу: =СУММ(A6:C6) (через двоеточие в формулах указываются диапазоны ячеек). Она будет вычислять сумму углов треугольника. При правильности вычислений она должна быть равна 180.
Для представления их в градусах – минутах – секундах и долях необходимо выполнить дополнительные вычисления. Отведем для градусов угла А ячейку (N2)A8, для минут –A9, для секунд и долей – A10. Для получения градусов необходимо отбросить у величины, хранящейся в ячейке A6 дробную часть. Это можно сделать помещением в A8 формулы:
=ОКРВНИЗ(A6;1). Для получения минут в ячейку A9 поместим формулу:
=ОКРВНИЗ((A6-A8)*60;1). Для получения секунд с долями в A10 поместим формулу: =(A6-(A8+A9/60))*3600.
Для углов B и C необходимо поступать аналогично, выбрав для них по три ячейки B8, B9, B10, C8, C9, C10. Расчет дает для углов А, В и С:
Рис.1 Метод расчета углов треугольника
Рис.2 Проверка решения метода расчета углов треугольника
Ответ: А=23 гр 29 мин 54,8сек; B=120 гр 57 мин 49,5 сек; С=35 гр 32 мин 15,6 сек
Расчет неприступного расстояния
Для β1: =E4+F4/60;
Для AB1: =A4*SIN(G4*ПИ()/180)/SIN((180-D4-G4)*ПИ()/180);
Для ABcp: =СУММ(H4:H7)/4.
Рис.3 Расчет неприступного расстояния.
Рис.4 Проверка расчета неприступного расстояния.
Ответ: ABср=205,3956
Расчет превышения
Для h1-2: =B4*TAN(E4)+A4-F4 +0,0675*(B4/1000)^2;
Рис.5 Расчет превышения
Рис.6 Проверка расчета превышения
Ответ: h1-2=-21,6338
Решение прямой угловой засечки по формулам Юнга
Для β1: =E4+F4/60+G4/3600;
Для Xp: =(A4/TAN(РАДИАНЫ(L4))+C4/TAN(РАДИАНЫ(H4))-B4+D4)/(1/TAN(РАДИАНЫ(H4))+ 1/TAN(РАДИАНЫ(L4))).
Для Yp: =(B4/TAN(L4*ПИ()/180)+D4/TAN(H4*ПИ()/180)+A4-C4)/
(1/TAN(H4*ПИ()/180)+1/TAN(L4*ПИ()/180)).
Рис.7 Решение прямой угловой засечки по формулам Юнга
Рис.8 Проверка прямой угловой засечки по формулам Юнга
Ответ: Xp=52,59931; Yp=47,85545.
Решение прямой угловой засечки по формулам Гаусса
Для Xp: =(A4*TAN(I4)-C4*TAN(J4)+D4-B4)/((TAN(I4)-TAN(J4))).
=B4+(A7-A4)*TAN(I4);
Для Yp: =B4+(A7-A4)*TAN(I4).
Рис.9 Решение прямой угловой засечки по формулам Гаусса
Рис.10 Проверка решения прямой угловой засечки по формулам Гаусса
Ответ:Xp=49,07654; Yp=53,05962.
Решение обратной геодезической задачи
=ЕСЛИ(C3-A3<0;180+(180/ПИ())*ATAN((D3-B3)/(C3-A3));ЕСЛИ(D3-B3<0;360+(180/ПИ())*ATAN((D3-B3)/(C3-A3));(180/ПИ())*ATAN((D3-B3)/(C3-A3)))).
=ОКРВНИЗ(E3;1).
=(E3-F3)*60.
=КОРЕНЬ((D3-B3)^2+(C3-A3)^2).
Рис.11 Решение обратной геодезической задачи
Рис.12 Проверка решения обратной геодезической задачи
Ответ: α(г)=317; α(м)=1,49613; S1-2=8,656656.
Решение обратной угловой засечки по формулам Пранис-Праневича
В A8: =РАДИАНЫ(G4+H4/60). Аналогично, для β, используя для ввода ячейки I4, J4, а для формулы B8: =РАДИАНЫ(I4+J4/60).
В ячейку C8 поместим формулу для вычисления tgQ:
=((D4-B4)/TAN(A8)-(F4-D4)/TAN(B8)+A4-E4)/
((C4-A4)/TAN(A8)-(E4-C4)/TAN(B8)-B4+F4).
В ячейку D8 поместим формулу для вычисления N:
=(D4-B4)*(1/TAN(A8)-C8)-(C4-A4)*(1+C8/TAN(A8)).
В ячейки E8 и F8 поместим формулы для вычисления Δx и Δy:
=D8/(1+C8^2) и =E8*C8, а в ячейки G8 и H8 формулы для xp и yp: =C4+E8 и =D4+F8.
Рис.13 Решение обратной угловой засечки по формулам Пранис-Праневича
Рис.14 Проверка решения обратной угловой засечки по формулам Пранис-Праневича
Ответ: Xp=7,559063; Yp=8,930772.