8. Сортировка списков Пример 8.1. Пузырьковая сортировка

Идея этого метода заключается в следующем. На каждом шаге сравниваются два соседних элемента списка. Если оказывается, что они стоят неправильно, то есть предыдущий элемент меньше следующего, то они меняются местами. Этот процесс продолжаем до тех пор, пока есть пары соседних элементов, расположенные в неправильном порядке. Это и будет означать, что список отсортирован.

Реализуем пузырьковую сортировку посредством двух предикатов. Один из них, назовем его permutation, будет сравнивать два первых элемента списка и в случае, если первый окажется больше второго, менять их местами. Если же первая пара расположена в правильном порядке, этот предикат будет переходить к рассмотрению хвоста.

Основной предикат bubble будет осуществлять пузырьковую сортировку списка, используя вспомогательный предикат permutation.

/* переставляем первые два элемента, если первый больше второго */

permutation([X,Y|T],[Y,X|T]):- X>Y,!.

/*переходим к перестановкам в хвосте*/

permutation([X|T],[X|T1]):- permutation(T,T1).

/* вызываем предикат, осуществляющий перестановку */

bubble(L,L1):-

permutation(L,LL),

!, bubble(LL,L1). /* пытаемся еще раз отсортировать полученный список */

bubble(L,L). /* если перестановок не было, значит список отсортирован */

Но наш пузырьковый метод работает только до тех пор, пока есть хотя бы пара элементов списка, расположенных в неправильном порядке. Как только такие элементы закончились, предикат permutation терпит неудачу, а bubble переходит от правила к факту и возвращает в качестве второго аргумента отсортированный список.

Пример 8.2. Сортировка вставкой

Теперь рассмотрим сортировку вставкой. Она основана на том, что если хвост списка уже отсортирован, то достаточно поставить первый элемент списка на его место в хвосте, и весь список будет отсортирован. При реализации этой идеи создадим два предиката.

Задача предиката insert — вставить значение (голову исходного списка) в уже отсортированный список (хвост исходного списка), так чтобы он остался упорядоченным. Его первым аргументом будет вставляемое значение, вторым — отсортированный список, третьим — список, полученный вставкой первого аргумента в нужное место второго аргумента так, чтобы не нарушить порядок.

Предикат ins_sort, собственно, и будет организовывать сортировку исходного списка методом вставок. В качестве первого аргумента ему дают произвольный список, который нужно отсортировать. Вторым аргументом он возвращает список, состоящий из элементов исходного списка, стоящих в правильном порядке.

/* отсортированный пустой список остается пустым списком */

ins_sort([ ],[ ]).

/* T — хвост исходного списка,T_Sort — отсортированный хвост исходного списка */

ins_sort([H|T],L):- ins_sort(T,T_Sort), insert(H,T_Sort,L).

/* вставляем H (первый элемент исходного списка)в T_Sort, получаем L (список, состоящий из элементов исходного списка, стоящих по неубыванию) */

insert(X,[],[X]).

/* при вставке любого значения в пустой список, получаем одноэлементный список*/

/* если вставляемое значение больше головы списка,

значит его нужно вставлять в хвост */

insert(X,[H|T],[H|T1]):- X>H,!, insert(X,T,T1).

/* вставляем X в хвост T, в результате получаем список T1 */

insert(X,T,[X|T]).

/* это предложение (за счет отсечения в предыдущем правиле) выполняется,

только если вставляемое значение не больше головы списка T, значит,

добавляем его первым элементом в список T */