3.4. Моделирование схемы источника тока.

Рис.19. Принципиальная схема одиночного источника тока.

Составление описания схемы.

Все резисторы задаём через параметры. Для Re задаём отдельный параметр, а для резисторов базового делителя один параметр Rb с двумя множителями:

• Rb1 = {N0*Rb}, Rb2 = {N0*N*Rb},

• начальные значения: Rb в пределах (1 – 5)kΩ, N=N0=1.

Настройка базового делителя.

При развертке параметра N ~ от 1 до 20 установим его значение, при котором отрицательное напряжение на базе будет равно примерно – Vmns + (2 – 3)B.

Берём примерное значение отрицательного напряжения

Рис.20. График зависимости VB(q1) от параметра N.

Из графика находим примерное значение параметра N

При развертке параметра N0 ~ от 1 до 20 установить его значение, при котором ранее полученное значение напряжения на базе изменится не более, чем на 0.5V;

Рис.21. График зависимости VB(q1) от параметра N0.

Из графика находим примерное значение параметра N0

Настройка токов для входного каскада и ССУ.

При развертке параметра Re ~ от 0.01k до 5k получим значения, обеспечивающие токи для входного каскада и ССУ.

Рис.22. График зависимости IC(q1) = f(Re).

Для обеспечения током входного каскада (Ida=0.323mA), необходим резистор сопротивлением Re .

Для обеспечения током ССУ (Islc=32,4mA), необходим резистор сопротивлением Re .

Листинг программы моделирования источника тока

*CS

.lib nom.lib

.inc ScriptMM109.txt

.param Rb=1k N=10 N0=3 Re=1k

V2 mns 0 -15

q1 0 b1 e1 Q2N2857

q2 bc bc mns Q2N2857

Rb1 bc b1 {N0*Rb}

Rb2 b1 0 {N0*N*Rb}

Re1 e1 mns {Re}

*.DC param N 1 20 0.1

*.DC param N0 1 20 0.1

.DC param Re 0.1 10k 0.01k

.probe

+ VB(q1) IC(q1)

.end

Моделирование всего усилителя с использованием макромоделей

.lib nom.lib

.inc ScriptMM109.txt

.param Vdc=45m Vac=45m Vsin=45m Rv=200 Vin2=0

.param Rc=16.5k Ccor=1p

.param Rb=1k N=10 N0=3 Re1=4k Re2=0.02k Re3=0.5k

.param Rsl=0.01k

V1 pls 0 15

V2 mns 0 -15

Vin in1 0 {Vdc} AC {Vac} sin 0 {Vsin} 1k

Rv out 0 {Rv}

Xda pls in1 n1 n2 in2 DA

+ params: Rc={Rc} Ccor={Ccor}

Vin2 in2 0 {Vin2}

Xsl pls n1 n3 SL

+ params: Rsl={Rsl}

Xcs1 n2 mns CS

+params: Rb={Rb} N={N} N0={N0} Re={Re1}

Xcs2 n3 mns CS

+params: Rb={Rb} N={N} N0={N0} Re={Re2}

Xer pls n3 mns out ER

+ params: Re={Re3}

*DA TUNINGS

*.DC Vin 0 32m 0.1m

*.step param Ida 0.1m 2m 0.01m

*.step param Rc 1k 50k 0.5k

*.AC DEC 100 0.1 10k

*.tran 1m 14m 10m 10u

*ER TUNINGS

*.DC Vsl -2 2 0.1

*.DC param Rsl 0.1k 10k 0.1k

*SL TUNINGS

*.DC param Re2 0.5k 5k 0.1k

*CS TUNINGS

*.DC param N 1 20 0.1

*.DC param N0 1 20 0.1

*.DC param Re 0.1 50k 0.1k

*MAIN TUNINGS

*.AC DEC 50 1k 10meg

*.step dec param Ccor 0.1p 1n 20

*.tran 1m 14m 10m 10u

*DA PROBES

.probe IB(Xda.q1) IB(Xda.q2) VB(Xda.q1)

+VC(Xda.q1) VC(Xda.q2) VE(Xda.q1) VB(Xda.q2)

*ER PROBES

.probe VE(Xer.q1) VB(Xer.q1)

*SL PROBES

.probe V([n3])

*CS PROBES

.probe VB(Xcs1.q1) IC(Xcs1.q1)

*MAIN PROBES

.probe V([out]) V([in1])

.end

Описание схем в файле ScriptMM109.txt

.model Q2N2857 NPN(Is=69.28E-18 Xti=3 Eg=1.11 Vaf=100 Bf=288 dev/gauss 20% Ne=1.167

+ Ise=69.28E-18 Ikf=21.59m Xtb=1.5 Br=1.219 Nc=2 Isc=0 Ikr=0 Rc=4

+ Cjc=893.1f Mjc=.3017 Vjc=.75 Fc=.5 Cje=939.8f Mje=.3453 Vje=.75

+ Tr=1.607n Tf=115.7p Itf=.27 Vtf=10 Xtf=30 Rb=10)

.MODEL Rt RES(R=1 dev/gauss 5% TC1=3e-4)

.subckt DA pls in1 sl cs in2

+ params: Rc=16.5k Ccor=1p

q1 sl in1 cs Q2N2857

q2 c2 in2 cs Q2N2857

Rc1 sl pls Rt {Rc}

Rc2 c2 pls Rt {Rc}

Ccor sl pls {Ccor}

.ends

.subckt SL pls da ercs

+ params: Rsl=0.01k

q1 pls da e1 Q2N2857

Rslc e1 ercs {Rsl}

.ends

.subckt CS dasl mns

+params: Rb=1k N=10 N0=3 Re=1k

q1 dasl b1 e1 Q2N2857

q2 bc bc mns Q2N2857

Rb1 bc b1 Rt {N0*Rb}

Rb2 b1 dasl Rt {N0*N*Rb}

Re e1 mns Rt {Re}

.ends

.subckt ER pls sl mns out

+ params: Re=0.5k

q1 pls sl out Q2N2857

Re1 out mns Rt {Re}

.ends