Добавил:
Upload Опубликованный материал нарушает ваши авторские права? Сообщите нам.
Вуз: Предмет: Файл:
Metoda_po_inf_ch_2.doc
Скачиваний:
2
Добавлен:
01.07.2025
Размер:
2 Мб
Скачать
☆

6. Линейная алгебра

В Maple реализованы специальные возможности для работы с таким классическим математическим курсом как линейная алгебра. Основные команды собраны в пакетах linalg и student.

6.1. Основные операции над матрицами

Пример 1 (создание матриц и векторов).

Заметим сразу, что матрицы и вектора по сути своей это переменные типа массив и список. Основное отличие в том, что добавлены операции сложения и умножения. В силу этого, при загрузке пакета linalg система печатает предупреждение о переопределении ряда операций. Итак, разные определения матриц

> restart: with(linalg):

> A:=matrix([[5,w],[f(x),6]]);

> B:=matrix(2,2,[1,2,3,4]);

> f:=(i,j)->x^(a*i+b*j);

> C:=matrix(2,2,f);

> dC:=map(diff,C,x);

Частично заданные матрицы

> A:=matrix(2,2,[x,y]);

В этом примере A[2,1] означает неопределенность данного элемента матрицы в данный момент

> B:=matrix([col(A,1..2)]);

Некоторые матрицы специального вида

> A:=diag(a,b,c,d);

> B:=array(1..4,1..4,identity): eval(B);

> B:= array(symmetric, 1..3,1..3, [ [0,x,y], [x,0,z] ] ):

> eval(B);

В этом примере знак вопроса означает неопределенность элемента матрицы. Тем не менее можно работать с этой матрицей. Например

> B[1,2];

> B[3,3];

Различные определения векторов

> a:=vector([5,4,3,2,1]);

> b:=vector(4,0);

> c:=vector(4);

> d:=

Перечислим некоторые команды, позволяющие получать информацию о матричных и векторных переменных, изменять параметры матриц и векторов.

Пример 2 (структура матриц и векторов).

Размеры матриц определяются таким образом

> restart: with(linalg):

> A:= matrix(3,4);

> rowdim(A);

> coldim(A);

Строки и столбцы матриц можно

> A:= matrix(3,3,[1,2,3,4,5,6,7,8,9]);

выделять

> row(A,2);

> col(A,2..3);

удалять

> B:=delrows(A, 2..3);

> C:=delcols(A, 1..1);

добавлять (команда addrow(A, r1, r2, m) возвращает матрицу B в которой строка r2 заменена на строку m*row(A,r1) + row(A,r2)):

> B:=addrow(A,1,2,10);

> C:=addcol(A,1,2,-x);

умножать

> B:=mulrow(A, 2, 2);

> C:=mulcol(A, 2, x);

переставлять

> A:= array( [[1,2,x],[3,4,y]] );

> swaprow(A, 1, 2);

> swapcol(A, 2, 3);

Матрицы можно соединять, выделять из них подматрицы и т.д.

Перейдем к командам, которые реализуют основные векторные и матричные операции. Начнем с самых простых и часто используемых операций линейной алгебры.

Пример 3 (операции сложения и умножения).

Для сложения или умножения матриц и векторов используют многоцелевую команду

evalm. Например, зададим матрицы и вектор

> restart: with(linalg):

> A:= array( [[1,2],[3,4]] );

> B:= array( [[0,1],[1,0]] );

> c:= array( [4,5] );

и посмотрим на синтаксис этих операций

> evalm(A+B);

> evalm(A&*B);

> evalm(A&*c);

Так как опреция умножения над полем метриц некомутативна, то для этой операции предусмотрены и другие команды

> multiply(B,A);

> multiply(B,c);

а для векторов еще одна операция

> innerprod(c,B);

Умножить матрицу (вектор) на скаляр позволяет операция

> A:= array( [[1,2],[3,4]] );

> B:=scalarmul(A, x);

Для векторов добавлены еще две операции обычного и векторного произведения

> u:= vector( [1,x,y] );

> v:= vector( [z,1,1] );

> dotprod(u, v);

> crossprod(u, v);

Существует много встроенных команд для работы только с матрицами. Рассмотрим часть из них.

Пример 4 (всторенные операции с матрицами).

Определим матрицу

> restart: with(linalg):

> A := matrix(3,3, [1,2,3,x,y,z,a,b,c]);

Ее определитель, ранг и след равны

> det(A);

> rank(A);

> trace(A);

Сопряженная, транспонированная и обратная к ней равны

> B:=adj(A); # или adjoint

> C:=transpose(A);

> F:=inverse(A); # или evalm(1/A)

Можно найти эрмитову транспонированную, и некоторые другие матрицы, мы не будем на этом останавливаться.

Соседние файлы в предмете [НЕСОРТИРОВАННОЕ]